ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Fermer un site web hébergeant un fichier d'Aide   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 06 novembre 2026, 17h18
Gregory Adam
Belgique Belgique

atoutfox.public.association

Re: Fermer un site web hébergeant un fichier d'Aide

Bonjour,
(1) Perso, j’estime que s’ils ouvrent une page html, ils peuvent la fermer
(2) Si vous le voulez quand-même il faut passer par ShellExecuteEx()

Exemple
- Pour lancer un navigateur :
=LaunchUrl('https://www.google.com/advanced_search?hl=fr')


- Vous pouvez lancer autant de pages que vous voulez
- Il suffit d’appeler =StopUrls() pour les fermer toutes

#define   TRUE .t.
#define     false .f.
#include  "FoxPro.h"



#define X_ANCHOR  _screen._x_Anchor

*_______________________________________________________________________________




=LaunchUrl('https://www.google.com/advanced_search?hl=fr')
=LaunchUrl('https://www.google.com/advanced_search?hl=fr')
= LaunchUrl('https://www.google.com/advanced_search?hl=fr')

wait 'Any key' window at 1,1

=StopUrls()




*_______________________________________________________________________________
function LaunchUrl(url)

  local success
  success = true

  local obj, n, hProcess


  do case
  case !m.success

  case !ShellInfoExecuteInfo_Object(@m.obj)
    assert false
    success = false

  case !m.obj.SetVerb('open')
    assert false
    success = false

  case !m.obj.SetFile(m.url)
    assert false
    success = false

  otherwise
    n = x_ShellExecuteExA(m.obj.ptr)

  endcase
  do case
  case !m.success

  case empty(m.n)
    assert false
    success = false

  case !m.obj.ShellInfoObj .Integer_Get(56, @m.hProcess)
    assert false
    success = false
  endcase

  do case
  case !m.success

  case inlist(vartype(X_ANCHOR), T_OBJECT)

  case !_screen.AddProperty(justext([X_ANCHOR]), createobject('Collection'))
    assert false
    success = false

  endcase

  do case
  case !m.success

  case !X_ANCHOR.Add(m.hProcess)
    assert false
    success = false
  endcase
  ?hProcess, x_GetProcessId(m.hProcess)

  return m.success

endfunc
*_______________________________________________________________________________
&& https://www.experts-exchange.com/questions/21023316/terminate-handle-with-shellexecuteEx.html
function StopUrls()

  local success
  success = true

  do case
  case !m.success

  case !inlist(vartype(X_ANCHOR), T_OBJECT)

  otherwise
    local hProcesss
    for each hProcesss in X_ANCHOR foxobject
      =StopUrl(hProcesss)

    endfor
    store null to X_ANCHOR
  endcase
  return m.success

endfunc
*_______________________________________________________________________________
function StopUrl(hProcess)

  local lpExitCode, returnCode, ret
  lpExitCode = 0

  returnCode = x_GetExitCodeProcess(m.hProcess, @m.lpExitCode)
  do case
  case empty(returnCode)

  case !inlist(lpExitCode, 259)  && STILL_ACTIVE

  otherwise
    ret =x_TerminateProcess(hProcess, 0)

  endcase
  =x_CloseHandle(m.hProcess)

endfunc
*_______________________________________________________________________________
*_______________________________________________________________________________
*===============================================================================
*===============================================================================
*===============================================================================
&& API
#define  DWORD    Long
#define T_HANDLE  long
#define T_POINTER  long
#define T_HANDLE  long
#define LPVOID    long
#define Size_T    long
#define T_BOOL     long
#define LPDWORD    long
*_______________________________________________________________________________
function x_GetProcessHeap()
  declare T_HANDLE GetProcessHeap in win32api as x_GetProcessHeap
  return x_GetProcessHeap()
endfunc
*_______________________________________________________________________________
function x_HeapAlloc(hHeap , flags, size)
  declare LPVOID  HeapAlloc in Win32api as x_HeapAlloc ;
    T_HANDLE hHeap,  DWORD dwFlags, SIZE_T dwBytes

  return x_HeapAlloc(m.hHeap, m.flags, m.size)
endfunc
*_______________________________________________________________________________
function x_HeapFree(hHeap, dwFlags, dwBytes)
  declare T_BOOL HeapFree in Win32api as x_HeapFree ;
    T_HANDLE hHeap,  DWORD dwFlags, T_POINTER dwBytes
  return x_HeapFree (m.hHeap, m.dwFlags, m.dwBytes)
endfunc
*_______________________________________________________________________________
function x_ShellExecuteExA(ptr)
  declare ShellExecuteExA in Shell32.dll as x_ShellExecuteExA ;
    LPVOID ptr

  return x_ShellExecuteExA(m.ptr)
endfunc
*_______________________________________________________________________________
function x_CloseHandle(handle)
  declare T_BOOL CloseHandle in Win32api as x_CloseHandle ;
    T_HANDLE handle

  return x_CloseHandle (m.handle)

endfunc
*_______________________________________________________________________________
function x_GetProcessId(hProcess)
  declare DWORD GetProcessId in Win32api as x_GetProcessId  ;
      T_HANDLE Process

  return x_GetProcessId  (hProcess)
endfunc
*_______________________________________________________________________________
function x_GetExitCodeProcess(hProcess, lpExitCode)
  declare T_BOOL GetExitCodeProcess in Win32api as x_GetExitCodeProcess ;
    T_HANDLE hProcess, LPDWORD @lpExitCode
  return x_GetExitCodeProcess(m.hProcess, @m.lpExitCode)
endfunc
*_______________________________________________________________________________
function x_TerminateProcess (hProcess, uExitCode)
  declare T_BOOL TerminateProcess in Win32api  as x_TerminateProcess ;
    T_HANDLE hProcess, long uExitCode

  return x_TerminateProcess(m.hProcess, m.uExitCode)
endfunc
*_______________________________________________________________________________
*===============================================================================
*===============================================================================
*===============================================================================

#define Session_Class  [_Session_Class_]
*===============================================================================
*===============================================================================
*===============================================================================
define class Session_Class as Session

  hidden  Application, ;
      ClassLibrary, Comment, Tag
  DataSession = 1

*_______________________________________________________________________________
protected function init()

  if( !dodefault() )
    return false
  endif

endfunc
*_______________________________________________________________________________
protected function Destroy()

  try
    =unbindevents(m.this)

  catch
    assert false
  endtry

  return DoDefault()
endfunc
*_______________________________________________________________________________
enddefine
*===============================================================================
*===============================================================================
*===============================================================================
#define HeapBuffer_CLASS  [_HeapBuffer_Class_]
*_______________________________________________________________________________
function HeapBuffer_Object(obj, size)

  try
    obj = createobject(HeapBuffer_CLASS, m.size)
  catch
    obj = null
  endtry
  return !isnull(m.obj)
endfunc
*_______________________________________________________________________________

*===============================================================================
*===============================================================================
*===============================================================================
define class HeapBuffer_CLASS as Session_Class

  && protected HeapPtr, BufferPtr

  HeapPtr  = 0
  BufferPtr = 0

  Ptr = 0
*_______________________________________________________________________________
#define HEAP_NO_SERIALIZE               0x00000001
#define HEAP_ZERO_MEMORY                0x00000008

protected function Init(size)

  local success
  success = true

  do case
  case !m.success

  case !dodefault()
    assert false
    success = false

  otherwise
    this.HeapPtr = x_GetProcessHeap ()
    this.BufferPtr = x_HeapAlloc(m.this.HeapPtr, bitor(HEAP_NO_SERIALIZE,HEAP_ZERO_MEMORY), m.size)

    if( empty(m.this.BufferPtr ) )
      assert false
      success = false
    endif
  endcase

  return m.success
endfunc
*_______________________________________________________________________________
protected function Destroy()

  if( empty(x_HeapFree (m.this.HeapPtr, bitor(HEAP_NO_SERIALIZE,HEAP_ZERO_MEMORY), m.this.BufferPtr)) )
    assert false
  endif

  return dodefault()
endfunc
*_______________________________________________________________________________
protected function Ptr_access()
  return m.this.BufferPtr
endfunc
*_______________________________________________________________________________
protected function Ptr_assign(z)
  error 1740, 'Ptr'
endfunc
*_______________________________________________________________________________
function Integer_Get(offset, val)

  val = ctobin(sys(2600, m.this.BufferPtr + m.offset, 4), '4rs')
endfunc
*_______________________________________________________________________________
function Integer_Put(offset, val )

  =sys(2600, m.this.BufferPtr + m.offset, 4, bintoc(m.val, '4rs'))
endfunc
*_______________________________________________________________________________
function String_Put(offset, s)
  =sys(2600, m.this.BufferPtr + m.offset, len(m.s), m.s)
endfunc
*_______________________________________________________________________________
enddefine
*===============================================================================
*===============================================================================
*===============================================================================

#define ShellInfoExecuteInfo_Class  [_ShellInfoExecuteInfo_Class_]
*_______________________________________________________________________________
function ShellInfoExecuteInfo_Object(obj)

  try
    obj = createobject(ShellInfoExecuteInfo_Class)
  catch
    obj = null
  endtry
  return !isnull(m.obj)
endfunc
*_______________________________________________________________________________

#define SEE_MASK_NOCLOSEPROCESS  0x00000040

#if false && https://learn.microsoft.com/en-us/windows/win32/api/shellapi/nf-shellapi-shellexecuteexa
typedef struct _SHELLEXECUTEINFOA {
0   DWORD     cbSize;
4   ULONG     fMask;
8   HWND      hwnd;
12  LPCSTR    lpVerb;
16  LPCSTR    lpFile;
20  LPCSTR    lpParameters;
24  LPCSTR    lpDirectory;
28  int       nShow;
32  HINSTANCE hInstApp;
36  void      *lpIDList;
40  LPCSTR    lpClass;
44  HKEY      hkeyClass;
48  DWORD     dwHotKey;
52  union {
    HANDLE hIcon;
    HANDLE hMonitor;
  } DUMMYUNIONNAME;
56  HANDLE    hProcess;
} SHELLEXECUTEINFOA, *LPSHELLEXECUTEINFOA;

#endif
*===============================================================================
*===============================================================================
*===============================================================================
define class ShellInfoExecuteInfo_Class as Session_Class
  ShellInfoObj = null
  VerbObj = null
  FileObj = null

  Ptr = 0
*_______________________________________________________________________________
protected function Ptr_access()
  return m.this.ShellInfoObj .BufferPtr
endfunc
*_______________________________________________________________________________
protected function Ptr_assign(z)
  error 1740, 'Ptr'
endfunc
*_______________________________________________________________________________

*_______________________________________________________________________________

protected function Init()

  local success
  success = true

  do case
  case !m.success

  case !dodefault()
    assert false
    success = false

  case !m.this.SetProperties()
    assert false
    success = false
  endcase

  return m.success
endfunc
*_______________________________________________________________________________
protected function Destroy()
  store null to ;
      this.ShellInfoObj, ;
      this.VerbObj, ;
      this.FileObj

  return DoDefault()
endfunc
*_______________________________________________________________________________
protected function SetProperties()

  local success
  success = true

  local obj

  local success
  success = true

  do case
  case !m.success

  case !HeapBuffer_Object(@m.obj, 60)
    assert false
    success = false

  case !m.this.AddProperty('ShellInfoObj', m.obj)
    assert false
    success = false

  && 0 cbSize
  case !m.obj.Integer_Put(0, 60)
    assert false
    success = false

  && 4 fMask
  case !m.obj.Integer_Put(4, SEE_MASK_NOCLOSEPROCESS)
    assert false
    success = false

  && 8 HWND
  case !m.obj.Integer_Put(8, 0)
    assert false
    success = false

  && verb 12

  && File 16

  && 20 lpParameters
  case !m.obj.Integer_Put(20, 0)
    assert false
    success = false

  && 24 lpDirectory
  case !m.obj.Integer_Put(24, 0)
    assert false
    success = false

  && 28 nShow
  case !m.obj.Integer_Put(28, 1)
    assert false
    success = false

  && 32 hInstApp

  && 36 lpIDList

  && 40 lpClass

  && 44 hkeyClass

  && 48 dwHotKey

  && 52 DUMMYUNIONNAME

  && 56 hProcess
  case !m.obj.Integer_Put(56, 0)
    assert false
    success = false
  endcase
  return m.success
endfunc
*_______________________________________________________________________________
function SetVerb(s)
  local success
  success = true

  local obj

  local success
  success = true

  do case
  case !m.success

  case !HeapBuffer_Object(@m.obj, len(m.s)+1)
    assert false
    success = false

  case !m.this.AddProperty('VerbObj', m.obj)
    assert false
    success = false

  case !m.obj.String_Put(0, m.s)
    assert false
    success = false

  case !m.this.ShellInfoObj.Integer_Put(12, m.obj.Ptr)
    assert false
    success = false
  endcase
  return m.success
endfunc
*_______________________________________________________________________________
function SetFile(s)
  local success
  success = true

  local obj

  local success
  success = true

  do case
  case !m.success

  case !HeapBuffer_Object(@m.obj, len(m.s)+1)
    assert false
    success = false

  case !m.this.AddProperty('FileObj', m.obj)
    assert false
    success = false

  case !m.obj.String_Put(0, m.s)
    assert false
    success = false

  case !m.this.ShellInfoObj.Integer_Put(16, m.obj.Ptr)
    assert false
    success = false
  endcase
  return m.success
endfunc
*_______________________________________________________________________________
enddefine

*===============================================================================
*===============================================================================
*===============================================================================





Journal

Francis Faure pense que ce message est la bonne réponse ou qu'il est utile
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000020380
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3